summaryrefslogtreecommitdiff
path: root/oh-my-zsh/plugins/tmux
diff options
context:
space:
mode:
Diffstat (limited to 'oh-my-zsh/plugins/tmux')
-rw-r--r--oh-my-zsh/plugins/tmux/README.md43
-rw-r--r--oh-my-zsh/plugins/tmux/tmux.extra.conf2
-rw-r--r--oh-my-zsh/plugins/tmux/tmux.only.conf1
-rw-r--r--oh-my-zsh/plugins/tmux/tmux.plugin.zsh113
4 files changed, 159 insertions, 0 deletions
diff --git a/oh-my-zsh/plugins/tmux/README.md b/oh-my-zsh/plugins/tmux/README.md
new file mode 100644
index 0000000..7348f77
--- /dev/null
+++ b/oh-my-zsh/plugins/tmux/README.md
@@ -0,0 +1,43 @@
+# tmux
+
+This plugin provides aliases for [tmux](https://tmux.github.io/), the terminal multiplexer.
+To use it add `tmux` to the plugins array in your zshrc file.
+
+```zsh
+plugins=(... tmux)
+```
+
+The plugin also supports the following:
+
+- determines if tmux is installed or not, if not, prompts user to install tmux
+- determines if the terminal supports the 256 colors or not, sets the appropriate configuration variable
+- sets the correct local config file to use
+
+## Aliases
+
+| Alias | Command | Description |
+| ---------- | -------------------------- | -------------------------------------------------------- |
+| `ta` | tmux attach -t | Attach new tmux session to already running named session |
+| `tad` | tmux attach -d -t | Detach named tmux session |
+| `ts` | tmux new-session -s | Create a new named tmux session |
+| `tl` | tmux list-sessions | Displays a list of running tmux sessions |
+| `tksv` | tmux kill-server | Terminate all running tmux sessions |
+| `tkss` | tmux kill-session -t | Terminate named running tmux session |
+| `tmux` | `_zsh_tmux_plugin_run` | Start a new tmux session |
+| `tmuxconf` | `$EDITOR $ZSH_TMUX_CONFIG` | Open .tmux.conf file with an editor |
+
+## Configuration Variables
+
+| Variable | Description |
+| ----------------------------------- | ----------------------------------------------------------------------------- |
+| `ZSH_TMUX_AUTOSTART` | Automatically starts tmux (default: `false`) |
+| `ZSH_TMUX_AUTOSTART_ONCE` | Autostart only if tmux hasn't been started previously (default: `true`) |
+| `ZSH_TMUX_AUTOCONNECT` | Automatically connect to a previous session if it exits (default: `true`) |
+| `ZSH_TMUX_AUTOQUIT` | Automatically closes terminal once tmux exits (default: `ZSH_TMUX_AUTOSTART`) |
+| `ZSH_TMUX_FIXTERM` | Sets `$TERM` to 256-color term or not based on current terminal support |
+| `ZSH_TMUX_ITERM2` | Sets the `-CC` option for iTerm2 tmux integration (default: `false`) |
+| `ZSH_TMUX_FIXTERM_WITHOUT_256COLOR` | `$TERM` to use for non 256-color terminals (default: `screen`) |
+| `ZSH_TMUX_FIXTERM_WITH_256COLOR` | `$TERM` to use for 256-color terminals (default: `screen-256color` |
+| `ZSH_TMUX_CONFIG` | Set the configuration path (default: `$HOME/.tmux.conf`) |
+| `ZSH_TMUX_UNICODE` | Set `tmux -u` option to support unicode |
+| `ZSH_TMUX_DEFAULT_SESSION_NAME` | Set tmux default session name when autostart is enabled |
diff --git a/oh-my-zsh/plugins/tmux/tmux.extra.conf b/oh-my-zsh/plugins/tmux/tmux.extra.conf
new file mode 100644
index 0000000..c4aaad0
--- /dev/null
+++ b/oh-my-zsh/plugins/tmux/tmux.extra.conf
@@ -0,0 +1,2 @@
+set -g default-terminal $ZSH_TMUX_TERM
+source-file $ZSH_TMUX_CONFIG \ No newline at end of file
diff --git a/oh-my-zsh/plugins/tmux/tmux.only.conf b/oh-my-zsh/plugins/tmux/tmux.only.conf
new file mode 100644
index 0000000..0734df3
--- /dev/null
+++ b/oh-my-zsh/plugins/tmux/tmux.only.conf
@@ -0,0 +1 @@
+set -g default-terminal $ZSH_TMUX_TERM
diff --git a/oh-my-zsh/plugins/tmux/tmux.plugin.zsh b/oh-my-zsh/plugins/tmux/tmux.plugin.zsh
new file mode 100644
index 0000000..311c2e6
--- /dev/null
+++ b/oh-my-zsh/plugins/tmux/tmux.plugin.zsh
@@ -0,0 +1,113 @@
+if ! (( $+commands[tmux] )); then
+ print "zsh tmux plugin: tmux not found. Please install tmux before using this plugin." >&2
+ return 1
+fi
+
+# CONFIGURATION VARIABLES
+# Automatically start tmux
+: ${ZSH_TMUX_AUTOSTART:=false}
+# Only autostart once. If set to false, tmux will attempt to
+# autostart every time your zsh configs are reloaded.
+: ${ZSH_TMUX_AUTOSTART_ONCE:=true}
+# Automatically connect to a previous session if it exists
+: ${ZSH_TMUX_AUTOCONNECT:=true}
+# Automatically close the terminal when tmux exits
+: ${ZSH_TMUX_AUTOQUIT:=$ZSH_TMUX_AUTOSTART}
+# Set term to screen or screen-256color based on current terminal support
+: ${ZSH_TMUX_FIXTERM:=true}
+# Set '-CC' option for iTerm2 tmux integration
+: ${ZSH_TMUX_ITERM2:=false}
+# The TERM to use for non-256 color terminals.
+# Tmux states this should be screen, but you may need to change it on
+# systems without the proper terminfo
+: ${ZSH_TMUX_FIXTERM_WITHOUT_256COLOR:=screen}
+# The TERM to use for 256 color terminals.
+# Tmux states this should be screen-256color, but you may need to change it on
+# systems without the proper terminfo
+: ${ZSH_TMUX_FIXTERM_WITH_256COLOR:=screen-256color}
+# Set the configuration path
+: ${ZSH_TMUX_CONFIG:=$HOME/.tmux.conf}
+# Set -u option to support unicode
+: ${ZSH_TMUX_UNICODE:=false}
+
+# ALIASES
+
+alias ta='tmux attach -t'
+alias tad='tmux attach -d -t'
+alias ts='tmux new-session -s'
+alias tl='tmux list-sessions'
+alias tksv='tmux kill-server'
+alias tkss='tmux kill-session -t'
+alias tmuxconf='$EDITOR $ZSH_TMUX_CONFIG'
+
+# Determine if the terminal supports 256 colors
+if [[ $terminfo[colors] == 256 ]]; then
+ export ZSH_TMUX_TERM=$ZSH_TMUX_FIXTERM_WITH_256COLOR
+else
+ export ZSH_TMUX_TERM=$ZSH_TMUX_FIXTERM_WITHOUT_256COLOR
+fi
+
+# Handle $0 according to the standard:
+# https://zdharma-continuum.github.io/Zsh-100-Commits-Club/Zsh-Plugin-Standard.html
+0="${${ZERO:-${0:#$ZSH_ARGZERO}}:-${(%):-%N}}"
+0="${${(M)0:#/*}:-$PWD/$0}"
+
+# Set the correct local config file to use.
+if [[ "$ZSH_TMUX_ITERM2" == "false" && -e "$ZSH_TMUX_CONFIG" ]]; then
+ export ZSH_TMUX_CONFIG
+ export _ZSH_TMUX_FIXED_CONFIG="${0:h:a}/tmux.extra.conf"
+else
+ export _ZSH_TMUX_FIXED_CONFIG="${0:h:a}/tmux.only.conf"
+fi
+
+# Wrapper function for tmux.
+function _zsh_tmux_plugin_run() {
+ if [[ -n "$@" ]]; then
+ command tmux "$@"
+ return $?
+ fi
+
+ local -a tmux_cmd
+ tmux_cmd=(command tmux)
+ [[ "$ZSH_TMUX_ITERM2" == "true" ]] && tmux_cmd+=(-CC)
+ [[ "$ZSH_TMUX_UNICODE" == "true" ]] && tmux_cmd+=(-u)
+
+ # Try to connect to an existing session.
+ if [[ -n "$ZSH_TMUX_DEFAULT_SESSION_NAME" ]]; then
+ [[ "$ZSH_TMUX_AUTOCONNECT" == "true" ]] && $tmux_cmd attach -t $ZSH_TMUX_DEFAULT_SESSION_NAME
+ else
+ [[ "$ZSH_TMUX_AUTOCONNECT" == "true" ]] && $tmux_cmd attach
+ fi
+
+ # If failed, just run tmux, fixing the TERM variable if requested.
+ if [[ $? -ne 0 ]]; then
+ if [[ "$ZSH_TMUX_FIXTERM" == "true" ]]; then
+ tmux_cmd+=(-f "$_ZSH_TMUX_FIXED_CONFIG")
+ elif [[ -e "$ZSH_TMUX_CONFIG" ]]; then
+ tmux_cmd+=(-f "$ZSH_TMUX_CONFIG")
+ fi
+ if [[ -n "$ZSH_TMUX_DEFAULT_SESSION_NAME" ]]; then
+ $tmux_cmd new-session -s $ZSH_TMUX_DEFAULT_SESSION_NAME
+ else
+ $tmux_cmd new-session
+ fi
+ fi
+
+ if [[ "$ZSH_TMUX_AUTOQUIT" == "true" ]]; then
+ exit
+ fi
+}
+
+# Use the completions for tmux for our function
+compdef _tmux _zsh_tmux_plugin_run
+# Alias tmux to our wrapper function.
+alias tmux=_zsh_tmux_plugin_run
+
+# Autostart if not already in tmux and enabled.
+if [[ -z "$TMUX" && "$ZSH_TMUX_AUTOSTART" == "true" && -z "$INSIDE_EMACS" && -z "$EMACS" && -z "$VIM" ]]; then
+ # Actually don't autostart if we already did and multiple autostarts are disabled.
+ if [[ "$ZSH_TMUX_AUTOSTART_ONCE" == "false" || "$ZSH_TMUX_AUTOSTARTED" != "true" ]]; then
+ export ZSH_TMUX_AUTOSTARTED=true
+ _zsh_tmux_plugin_run
+ fi
+fi
generated by cgit v1.2.3 (git 2.25.1) at 2025-02-23 14:12:14 +0000