From edc449275b6c04445f58b108ca0937a87c1e8430 Mon Sep 17 00:00:00 2001
From: Aditya <bluenerd@protonmail.com>
Date: Mon, 27 Feb 2023 20:04:56 +0530
Subject: add zsh

---
 oh-my-zsh/lib/grep.zsh | 41 +++++++++++++++++++++++++++++++++++++++++
 1 file changed, 41 insertions(+)
 create mode 100644 oh-my-zsh/lib/grep.zsh

(limited to 'oh-my-zsh/lib/grep.zsh')

diff --git a/oh-my-zsh/lib/grep.zsh b/oh-my-zsh/lib/grep.zsh
new file mode 100644
index 0000000..54e0f69
--- /dev/null
+++ b/oh-my-zsh/lib/grep.zsh
@@ -0,0 +1,41 @@
+__GREP_CACHE_FILE="$ZSH_CACHE_DIR"/grep-alias
+
+# See if there's a cache file modified in the last day
+__GREP_ALIAS_CACHES=("$__GREP_CACHE_FILE"(Nm-1))
+if [[ -n "$__GREP_ALIAS_CACHES" ]]; then
+    source "$__GREP_CACHE_FILE"
+else
+    grep-flags-available() {
+        command grep "$@" "" &>/dev/null <<< ""
+    }
+
+    # Ignore these folders (if the necessary grep flags are available)
+    EXC_FOLDERS="{.bzr,CVS,.git,.hg,.svn,.idea,.tox}"
+
+    # Check for --exclude-dir, otherwise check for --exclude. If --exclude
+    # isn't available, --color won't be either (they were released at the same
+    # time (v2.5): https://git.savannah.gnu.org/cgit/grep.git/tree/NEWS?id=1236f007
+    if grep-flags-available --color=auto --exclude-dir=.cvs; then
+        GREP_OPTIONS="--color=auto --exclude-dir=$EXC_FOLDERS"
+    elif grep-flags-available --color=auto --exclude=.cvs; then
+        GREP_OPTIONS="--color=auto --exclude=$EXC_FOLDERS"
+    fi
+
+    if [[ -n "$GREP_OPTIONS" ]]; then
+        # export grep, egrep and fgrep settings
+        alias grep="grep $GREP_OPTIONS"
+        alias egrep="grep -E $GREP_OPTIONS"
+        alias fgrep="grep -F $GREP_OPTIONS"
+
+        # write to cache file if cache directory is writable
+        if [[ -w "$ZSH_CACHE_DIR" ]]; then
+            alias -L grep egrep fgrep >| "$__GREP_CACHE_FILE"
+        fi
+    fi
+
+    # Clean up
+    unset GREP_OPTIONS EXC_FOLDERS
+    unfunction grep-flags-available
+fi
+
+unset __GREP_CACHE_FILE __GREP_ALIAS_CACHES
-- 
cgit v1.2.3