From edc449275b6c04445f58b108ca0937a87c1e8430 Mon Sep 17 00:00:00 2001
From: Aditya <bluenerd@protonmail.com>
Date: Mon, 27 Feb 2023 20:04:56 +0530
Subject: add zsh

---
 oh-my-zsh/plugins/lando/lando.plugin.zsh | 41 ++++++++++++++++++++++++++++++++
 1 file changed, 41 insertions(+)
 create mode 100644 oh-my-zsh/plugins/lando/lando.plugin.zsh

(limited to 'oh-my-zsh/plugins/lando/lando.plugin.zsh')

diff --git a/oh-my-zsh/plugins/lando/lando.plugin.zsh b/oh-my-zsh/plugins/lando/lando.plugin.zsh
new file mode 100644
index 0000000..af53e7e
--- /dev/null
+++ b/oh-my-zsh/plugins/lando/lando.plugin.zsh
@@ -0,0 +1,41 @@
+# Settings
+: ${LANDO_ZSH_SITES_DIRECTORY:="$HOME/Sites"}
+: ${LANDO_ZSH_CONFIG_FILE:=.lando.yml}
+
+# Enable multiple commands with lando.
+function artisan \
+         composer \
+         drush \
+         gulp \
+         npm \
+         php \
+         wp \
+         yarn {
+  if checkForLandoFile; then
+    lando "$0" "$@"
+  else
+    command "$0" "$@"
+  fi
+}
+
+# Check for the file in the current and parent directories.
+checkForLandoFile() {
+  # Only bother checking for lando within the Sites directory.
+  if [[ "$PWD/" != "$LANDO_ZSH_SITES_DIRECTORY"/* ]]; then
+    # Not within $LANDO_ZSH_SITES_DIRECTORY
+    return 1
+  fi
+
+  local curr_dir="$PWD"
+  # Checking for file: $LANDO_ZSH_CONFIG_FILE within $LANDO_ZSH_SITES_DIRECTORY...
+  while [[ "$curr_dir" != "$LANDO_ZSH_SITES_DIRECTORY" ]]; do
+    if [[ -f "$curr_dir/$LANDO_ZSH_CONFIG_FILE" ]]; then
+      return 0
+    fi
+    curr_dir="${curr_dir:h}"
+  done
+
+  # Could not find $LANDO_ZSH_CONFIG_FILE in the current directory
+  # or in any of its parents up to $LANDO_ZSH_SITES_DIRECTORY.
+  return 1
+}
\ No newline at end of file
-- 
cgit v1.2.3