From edc449275b6c04445f58b108ca0937a87c1e8430 Mon Sep 17 00:00:00 2001
From: Aditya <bluenerd@protonmail.com>
Date: Mon, 27 Feb 2023 20:04:56 +0530
Subject: add zsh

---
 oh-my-zsh/plugins/rbw/README.md      | 22 ++++++++++++++++++
 oh-my-zsh/plugins/rbw/rbw.plugin.zsh | 43 ++++++++++++++++++++++++++++++++++++
 2 files changed, 65 insertions(+)
 create mode 100644 oh-my-zsh/plugins/rbw/README.md
 create mode 100644 oh-my-zsh/plugins/rbw/rbw.plugin.zsh

(limited to 'oh-my-zsh/plugins/rbw')

diff --git a/oh-my-zsh/plugins/rbw/README.md b/oh-my-zsh/plugins/rbw/README.md
new file mode 100644
index 0000000..cae36ce
--- /dev/null
+++ b/oh-my-zsh/plugins/rbw/README.md
@@ -0,0 +1,22 @@
+# Bitwarden (unofficial) CLI plugin
+
+This plugin adds completion for [rbw](https://github.com/doy/rbw), an unofficial
+CLI for [Bitwarden](https://bitwarden.com).
+
+To use it, add `rbw` to the plugins array in your zshrc file:
+
+```zsh
+plugins=(... rbw)
+```
+
+## `rbwpw`
+
+The `rbwpw` function is a wrapper around `rbw`. It copies the password in the
+clipboard for the service you ask for and clears the clipboard 20s later.
+The usage is as follows:
+
+```zsh
+rbwpw <service>
+```
+
+This plugin does not add any aliases.
diff --git a/oh-my-zsh/plugins/rbw/rbw.plugin.zsh b/oh-my-zsh/plugins/rbw/rbw.plugin.zsh
new file mode 100644
index 0000000..b6cecf8
--- /dev/null
+++ b/oh-my-zsh/plugins/rbw/rbw.plugin.zsh
@@ -0,0 +1,43 @@
+if (( ! $+commands[rbw] )); then
+  return
+fi
+
+# If the completion file doesn't exist yet, we need to autoload it and
+# bind it to `rbw`. Otherwise, compinit will have already done that.
+if [[ ! -f "$ZSH_CACHE_DIR/completions/_rbw" ]]; then
+  typeset -g -A _comps
+  autoload -Uz _rbw
+  _comps[rbw]=_rbw
+fi
+
+rbw gen-completions zsh >| "$ZSH_CACHE_DIR/completions/_rbw" &|
+
+# rbwpw function copies the password of a service to the clipboard
+# and clears it after 20 seconds
+function rbwpw {
+  if [[ $# -ne 1 ]]; then
+    echo "usage: rbwpw <service>"
+    return 1
+  fi
+  local service=$1
+  if ! rbw unlock; then
+    echo "rbw is locked"
+    return 1
+  fi
+  local pw=$(rbw get $service 2>/dev/null)
+  if [[ -z $pw ]]; then
+    echo "$service not found"
+    return 1
+  fi
+  echo -n $pw | clipcopy
+  echo "password for $service copied!"
+  {sleep 20 && clipcopy </dev/null 2>/dev/null} &|
+}
+
+function _rbwpw {
+  local -a services
+  services=("${(@f)$(rbw ls 2>/dev/null)}")
+  [[ -n "$services" ]] && compadd -a -- services
+}
+
+compdef _rbwpw rbwpw
-- 
cgit v1.2.3