add zsh

4 files changed, 158 insertions, 0 deletions

diff --git a/oh-my-zsh/plugins/1password/1password.plugin.zsh b/oh-my-zsh/plugins/1password/1password.plugin.zsh
new file mode 100644
index 0000000..941523c
--- /dev/null
+++ b/oh-my-zsh/plugins/1password/1password.plugin.zsh
@@ -0,0 +1,9 @@
+# Do nothing if op is not installed
+(( ${+commands[op]} )) || return
+
+# Load op completion
+eval "$(op completion zsh)"
+compdef _op op
+
+# Load opswd function
+autoload -Uz opswd
diff --git a/oh-my-zsh/plugins/1password/README.md b/oh-my-zsh/plugins/1password/README.md
new file mode 100644
index 0000000..ace6da8
--- /dev/null
+++ b/oh-my-zsh/plugins/1password/README.md
@@ -0,0 +1,40 @@
+# 1Password
+
+This plugin adds 1Password functionality to oh-my-zsh.
+
+To use, add `1password` to the list of plugins in your `.zshrc` file:
+
+```zsh
+plugins=(... 1password)
+```
+
+Then, you can use the command `opswd` to copy passwords for services into your
+clipboard.
+
+## `opswd`
+
+The `opswd` command is a wrapper around the `op` command. It takes a service
+name as an argument and copies the username, then the password for that service
+to the clipboard, after confirmation on the user part.
+
+If the service also contains a TOTP, it is copied to the clipboard after confirmation
+on the user part. Finally, after 20 seconds, the clipboard is cleared.
+
+For example, `opswd github.com` will put your GitHub username into your clipboard. Then,
+it will ask for confirmation to continue, and copy the password to your clipboard. Finally,
+if a TOTP is available, it will be copied to the clipboard after your confirmation.
+
+This function has completion support, so you can use tab completion to select which
+service you want to get.
+
+> NOTE: you need to be signed in for `opswd` to work. If you are using biometric unlock,
+> 1Password CLI will automatically prompt you to sign in. See:
+>
+> - [Get started with 1Password CLI 2: Sign in](https://developer.1password.com/docs/cli/get-started#sign-in)
+> - [Sign in to your 1Password account manually](https://developer.1password.com/docs/cli/sign-in-manually)
+
+## Requirements
+
+- [1Password CLI 2](https://developer.1password.com/docs/cli/get-started#install)
+
+  > NOTE: if you're using 1Password CLI 1, [see how to upgrade to CLI 2](https://developer.1password.com/docs/cli/upgrade).
diff --git a/oh-my-zsh/plugins/1password/_opswd b/oh-my-zsh/plugins/1password/_opswd
new file mode 100644
index 0000000..dbc094f
--- /dev/null
+++ b/oh-my-zsh/plugins/1password/_opswd
@@ -0,0 +1,19 @@
+#compdef opswd
+
+function _opswd() {
+  local -a services
+  services=("${(@f)$(op item list --categories Login --cache 2>/dev/null | awk 'NR != 1 { print $2 }')}")
+  [[ -z "$services" ]] || compadd -a -- services
+}
+
+# TODO: 2022-03-26: Remove support for op CLI 1
+autoload -Uz is-at-least
+is-at-least 2.0.0 $(op --version) || {
+  function _opswd() {
+    local -a services
+    services=("${(@f)$(op list items --categories Login 2>/dev/null | op get item - --fields title 2>/dev/null)}")
+    [[ -z "$services" ]] || compadd -a -- services
+  }
+}
+
+_opswd "$@"
diff --git a/oh-my-zsh/plugins/1password/opswd b/oh-my-zsh/plugins/1password/opswd
new file mode 100644
index 0000000..0f667d2
--- /dev/null
+++ b/oh-my-zsh/plugins/1password/opswd
@@ -0,0 +1,90 @@
+#autoload
+
+# opswd puts the password of the named service into the clipboard. If there's a
+# one time password, it will be copied into the clipboard after 10 seconds. The
+# clipboard is cleared after another 20 seconds.
+function opswd() {
+  if [[ $# -lt 1 ]]; then
+    echo "Usage: opswd <service>"
+    return 1
+  fi
+
+  local service=$1
+
+  # If not logged in, print error and return
+  op user list > /dev/null || return
+
+  local username
+  # Copy the username to the clipboard
+  if ! username=$(op item get "$service" --fields username 2>/dev/null); then
+    echo "error: could not obtain username for $service"
+    return 1
+  fi
+
+  echo -n "$username" | clipcopy
+  echo "✔ username for service $service copied to the clipboard. Press Enter to continue"
+  read
+
+  local password
+  # Copy the password to the clipboard
+  if ! password=$(op item get "$service" --fields password 2>/dev/null); then
+    echo "error: could not obtain password for $service"
+    return 1
+  fi
+
+  echo -n "$password" | clipcopy
+  echo "✔ password for $service copied to clipboard. Press Enter to continue"
+  read
+
+  # If there's a one time password, copy it to the clipboard
+  local totp
+  if totp=$(op item get --otp "$service" 2>/dev/null) && [[ -n "$totp" ]]; then
+    echo -n "$totp" | clipcopy
+    echo "✔ TOTP for $service copied to clipboard"
+  fi
+
+  (sleep 20 && clipcopy </dev/null 2>/dev/null) &!
+}
+
+# TODO: 2022-03-26: Remove support for op CLI 1
+autoload -Uz is-at-least
+is-at-least 2.0.0 $(op --version) || {
+  print -ru2 ${(%):-"%F{yellow}opswd: usage with op version $(op --version) is deprecated. Upgrade to CLI 2 and reload zsh.
+For instructions, see https://developer.1password.com/docs/cli/upgrade.%f"}
+
+  # opswd puts the password of the named service into the clipboard. If there's a
+  # one time password, it will be copied into the clipboard after 10 seconds. The
+  # clipboard is cleared after another 20 seconds.
+  function opswd() {
+    if [[ $# -lt 1 ]]; then
+      echo "Usage: opswd <service>"
+      return 1
+    fi
+
+    local service=$1
+
+    # If not logged in, print error and return
+    op list users > /dev/null || return
+
+    local password
+    # Copy the password to the clipboard
+    if ! password=$(op get item "$service" --fields password 2>/dev/null); then
+      echo "error: could not obtain password for $service"
+      return 1
+    fi
+
+    echo -n "$password" | clipcopy
+    echo "✔ password for $service copied to clipboard"
+
+    # If there's a one time password, copy it to the clipboard after 5 seconds
+    local totp
+    if totp=$(op get totp "$service" 2>/dev/null) && [[ -n "$totp" ]]; then
+      sleep 10 && echo -n "$totp" | clipcopy
+      echo "✔ TOTP for $service copied to clipboard"
+    fi
+
+    (sleep 20 && clipcopy </dev/null 2>/dev/null) &!
+  }
+}
+
+opswd "$@"