add zsh

2 files changed, 101 insertions, 0 deletions

diff --git a/oh-my-zsh/plugins/gnu-utils/README.md b/oh-my-zsh/plugins/gnu-utils/README.md
new file mode 100644
index 0000000..f5fa81e
--- /dev/null
+++ b/oh-my-zsh/plugins/gnu-utils/README.md
@@ -0,0 +1,38 @@
+# gnu-utils plugin
+
+This plugin binds GNU coreutils to their default names, so that you don't have
+to call them using their prefixed name, which starts with `g`. This is useful
+in systems which don't have GNU coreutils installed by default, mainly macOS
+or FreeBSD, which use BSD coreutils.
+
+To use it, add `gnu-utils` to the plugins array in your zshrc file:
+```zsh
+plugins=(... gnu-utils)
+```
+
+The plugin works by changing the path that the command hash points to, so
+instead of `ls` pointing to `/bin/ls`, it points to wherever `gls` is
+installed.
+
+Since `hash -rf` or `rehash` refreshes the command hashes, it also wraps
+`hash` and `rehash` so that the coreutils binding is always done again
+after calling these two commands.
+
+Look at the source code of the plugin to see which GNU coreutils are tried
+to rebind. Open an issue if there are some missing.
+
+## Other methods
+
+The plugin also documents two other ways to do this:
+
+1. Using a function wrapper, such that, for example, there exists a function
+named `ls` which calls `gls` instead. Since functions have a higher preference
+than commands, this ends up calling the GNU coreutil. It has also a higher
+preference over shell builtins (`gecho` is called instead of the builtin `echo`).
+
+2. Using an alias. This has an even higher preference than functions, but they
+could be overridden because of a user setting.
+
+## Author
+
+- [Sorin Ionescu](https://github.com/sorin-ionescu).
diff --git a/oh-my-zsh/plugins/gnu-utils/gnu-utils.plugin.zsh b/oh-my-zsh/plugins/gnu-utils/gnu-utils.plugin.zsh
new file mode 100644
index 0000000..9419127
--- /dev/null
+++ b/oh-my-zsh/plugins/gnu-utils/gnu-utils.plugin.zsh
@@ -0,0 +1,63 @@
+# ------------------------------------------------------------------------------
+#          FILE:  gnu-utils.plugin.zsh
+#   DESCRIPTION:  oh-my-zsh plugin file.
+#        AUTHOR:  Sorin Ionescu (sorin.ionescu@gmail.com)
+#       VERSION:  1.0.0
+# ------------------------------------------------------------------------------
+
+# Detect if GNU coreutils are installed by looking for gwhoami
+if [[ ! -x "${commands[gwhoami]}" ]]; then
+  return
+fi
+
+__gnu_utils() {
+  local -a gcmds
+  local gcmd
+
+  # coreutils 
+  gcmds=('g[' 'gbase64' 'gbasename' 'gcat' 'gchcon' 'gchgrp' 'gchmod'
+  'gchown' 'gchroot' 'gcksum' 'gcomm' 'gcp' 'gcsplit' 'gcut' 'gdate'
+  'gdd' 'gdf' 'gdir' 'gdircolors' 'gdirname' 'gdu' 'gecho' 'genv' 'gexpand'
+  'gexpr' 'gfactor' 'gfalse' 'gfmt' 'gfold' 'ggroups' 'ghead' 'ghostid'
+  'gid' 'ginstall' 'gjoin' 'gkill' 'glink' 'gln' 'glogname' 'gls' 'gmd5sum'
+  'gmkdir' 'gmkfifo' 'gmknod' 'gmktemp' 'gmv' 'gnice' 'gnl' 'gnohup' 'gnproc'
+  'god' 'gpaste' 'gpathchk' 'gpinky' 'gpr' 'gprintenv' 'gprintf' 'gptx' 'gpwd'
+  'greadlink' 'grm' 'grmdir' 'gruncon' 'gseq' 'gsha1sum' 'gsha224sum'
+  'gsha256sum' 'gsha384sum' 'gsha512sum' 'gshred' 'gshuf' 'gsleep' 'gsort'
+  'gsplit' 'gstat' 'gstty' 'gsum' 'gsync' 'gtac' 'gtail' 'gtee' 'gtest'
+  'gtimeout' 'gtouch' 'gtr' 'gtrue' 'gtruncate' 'gtsort' 'gtty' 'guname'
+  'gunexpand' 'guniq' 'gunlink' 'guptime' 'gusers' 'gvdir' 'gwc' 'gwho'
+  'gwhoami' 'gyes')
+
+  # findutils
+  gcmds+=('gfind' 'gxargs' 'glocate')
+
+  # Not part of either coreutils or findutils, installed separately.
+  gcmds+=('gsed' 'gtar' 'gtime' 'gmake' 'ggrep')
+
+  # can be built optionally
+  gcmds+=('ghostname')
+
+  for gcmd in "${gcmds[@]}"; do
+    # Do nothing if the command isn't found
+    (( ${+commands[$gcmd]} )) || continue
+    
+    # This method allows for builtin commands to be primary but it's
+    # lost if hash -r or rehash is executed, or if $PATH is updated.
+    # Thus, a preexec hook is needed, which will only run if whoami
+    # is not already rehashed.
+    #
+    hash ${gcmd[2,-1]}=${commands[$gcmd]}
+  done
+
+  return 0
+}
+
+__gnu_utils_preexec() {
+  # Run __gnu_utils when the whoami command is not already rehashed.
+  # This acts as a sign that we need to rehash all GNU utils.
+  [[ "${commands[whoami]}" = "${commands[gwhoami]}" ]] || __gnu_utils
+}
+
+autoload -Uz add-zsh-hook
+add-zsh-hook preexec __gnu_utils_preexec